flake.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

{
  inputs = {
    flake-utils.url = "github:numtide/flake-utils";
    nixpkgs.url = "github:nixos/nixpkgs/nixpkgs-unstable";
  };

  outputs = { self, nixpkgs, flake-utils, ... }:
    flake-utils.lib.eachDefaultSystem (system:
      let
        pkgs = import nixpkgs { inherit system; config.allowUnsupportedSystem = true; };
        inherit (pkgs) pkgsStatic;

        myPkgs = {
          libuv = pkgsStatic.libuv;
          luajit = pkgsStatic.luajit;
          qt = pkgs.qt6; # pkgsStatic.qt6
          lua-libluv = pkgs.callPackage (import ./nix/libluv.nix) {
            inherit (myPkgs) libuv luajit;
          };
          dkjson = pkgs.luajitPackages.dkjson;
          luassert = pkgs.luajitPackages.luassert;
          # lua-busted = pkgs.luajitPackages.busted;
        };

        dependencies = with myPkgs; [
          qt.qtbase
          qt.qtwebengine
          luajit
          libuv
          lua-libluv
          dkjson

          luassert
          # lua-busted
        ];
      in {
        devShells.default = pkgs.mkShell rec {
          buildInputs = with pkgs; [
            cmake
            ninja
            gnumake
            clang-tools
            pkg-config
            ccache
            gdb
            valgrind
            go-grip
            luajitPackages.ldoc
          ] ++ dependencies;

          LD_LIBRARY_PATH = "${pkgs.lib.makeLibraryPath buildInputs}";
        };

        packages.default = pkgs.stdenv.mkDerivation {
          pname = "null-browser";
          version = "0.0.0";
          src = ./.;

          buildInputs = dependencies;
          nativeBuildInputs = with pkgs; [
            cmake
            ninja
            myPkgs.qt.wrapQtAppsHook
            pkg-config
          ];
          dontUseCmakeConfigure = true;
          buildPhase = ''make build PREFIX=$out'';
          installPhase = ''make install PREFIX=$out'';

          meta.mainProgram = "null-browser";
        };
      });
}