Add newtons fractalmaster

4 files changed, 149 insertions, 0 deletions

diff --git a/src/main/kotlin/newton/NewtonProgram.kt b/src/main/kotlin/newton/NewtonProgram.kt
new file mode 100644
index 0000000..cb59c4d
--- /dev/null
+++ b/src/main/kotlin/newton/NewtonProgram.kt
@@ -0,0 +1,50 @@
+package newton
+
+import org.openrndr.application
+import org.openrndr.color.*
+import org.openrndr.draw.*
+import org.openrndr.extra.noise.filters.SimplexNoise3D
+import org.openrndr.math.Vector3
+import phenax.utils.*
+
+fun main() = application {
+  recordDuration(37.seconds())
+
+  if (recordingEnabled || screenshotEnabled) {
+    configure {
+      width = 1920
+      height = 1080
+      windowResizable = false
+    }
+  } else {
+    configure {
+      width = 640
+      height = 360
+      windowResizable = false
+    }
+  }
+
+  oliveProgram {
+    val cs by liveComputeShader("newton")
+
+    val outputBuffer = colorBuffer(width, height, type = ColorType.UINT8)
+
+    val size = Math.max(width, height) * 2
+    val noiseBuffer = colorBuffer(size, size, type = ColorType.UINT8)
+    val noiseFilter = SimplexNoise3D()
+    noiseFilter.scale = Vector3.ONE * 2.4
+    noiseFilter.octaves = 8
+    noiseFilter.premultipliedAlpha = true
+
+    extend {
+      noiseFilter.seed = Vector3(0.01, 0.01, 0.001)
+      noiseFilter.apply(emptyArray(), noiseBuffer)
+      cs.image("noise_texture", 1, noiseBuffer.imageBinding(0, ImageAccess.READ))
+
+      cs.uniform("seconds", seconds)
+      cs.image("output_image", 0, outputBuffer.imageBinding(0, ImageAccess.WRITE))
+      cs.execute(outputBuffer.width, outputBuffer.height, 1)
+      drawer.image(outputBuffer)
+    }
+  }
+}
diff --git a/src/main/resources/shaders/newton.glsl b/src/main/resources/shaders/newton.glsl
new file mode 100644
index 0000000..e53b153
--- /dev/null
+++ b/src/main/resources/shaders/newton.glsl
@@ -0,0 +1,99 @@
+#version 430
+layout(local_size_x = 1, local_size_y = 1) in;
+
+#include <utils>
+
+#define MAX_ITERATIONS 200
+
+const float antialiasing = 0.28;
+uniform float seconds = 0;
+layout(rgba8) uniform writeonly image2D output_image;
+
+float fabs(float a) {
+  return a > 0. ? a : -a;
+}
+
+float cosh(float val) {
+  float tmp = exp(val);
+  float cosH = (tmp + 1.0 / tmp) / 2.0;
+  return cosH;
+}
+
+float sinh(float val) {
+  float tmp = exp(val);
+  float sinH = (tmp - 1.0 / tmp) / 2.0;
+  return sinH;
+}
+
+vec2 cmul(vec2 a, vec2 b) {
+  return vec2(a.x * b.x - a.y * b.y, a.x * b.y + a.y * b.x);
+}
+
+vec2 cdiv(vec2 a, vec2 b) {
+  float denominator = b.x * b.x + b.y * b.y;
+  if (denominator == 0.) return a;
+  return cmul(a, vec2(b.x, -b.y)) / denominator;
+}
+
+vec2 cpow(vec2 z, int n) {
+  vec2 res = z;
+  for (int i = 0; i < 20; i++) {
+    if (i >= n - 1) break;
+    res = cmul(z, res);
+  }
+  return res;
+}
+
+vec2 cexp(vec2 z) {
+  return exp(z.x) * vec2(cos(z.y), sin(z.y));
+}
+
+vec2 get_step(vec2 z) {
+  vec2 value = cpow(z, 5) + 2.0 * cpow(z, 3) - vec2(1., 0.);
+  vec2 derivative = 5.0 * cpow(z, 4) + 3.0 * cpow(z, 2);
+  return cdiv(value, derivative);
+}
+
+vec3 image(vec2 uv) {
+  vec2 prevZ;
+  vec2 z = uv * 3.0;
+
+  float t = seconds / 20;
+  vec2 factor = vec2(mod(t + 0.1, 2), 0);
+
+  int iterations = 0;
+  for (int i = 0; i < MAX_ITERATIONS; i++) {
+    prevZ = z;
+    z = prevZ - cmul(factor, get_step(prevZ));
+
+    iterations++;
+    if (fabs(z.x - prevZ.x) < 0.001) break;
+  }
+
+  float val = float(iterations) * 10.0 / float(MAX_ITERATIONS);
+  float r = 0.1;
+  float g = min(val * 0.2, 0.7);
+  float b = min(val * 0.8, 0.7);
+  return srgb(r, g, b);
+}
+
+vec3 antialiased_image(vec2 uv) {
+  vec2 resolution = vec2(imageSize(output_image).xy);
+  float s = antialiasing / max(resolution.x, resolution.y);
+  vec3 sum = vec3(0);
+  int count = 0;
+  for (int i = -2; i < 2; i++)
+    for (int j = -2; j < 2; j++, count++)
+      sum += image(uv + vec2(i, j) * s);
+  return sum / count;
+}
+
+void main() {
+  vec2 resolution = vec2(imageSize(output_image).xy);
+  float aspect_ratio = resolution.y / resolution.x;
+  vec2 uv = (gl_GlobalInvocationID.xy - resolution * 0.5) * vec2(1.0, aspect_ratio) / resolution;
+
+  // vec3 color = image(uv);
+  vec3 color = antialiased_image(uv);
+  imageStore(output_image, ivec2(gl_GlobalInvocationID.xy), vec4(color, 1));
+}
diff --git a/video/newton.NewtonProgram.1080p.mp4 b/video/newton.NewtonProgram.1080p.mp4
new file mode 100644
index 0000000..b7d69e9
--- /dev/null
+++ b/video/newton.NewtonProgram.1080p.mp4
diff --git a/video/newton.NewtonProgram.mp4 b/video/newton.NewtonProgram.mp4
new file mode 100644
index 0000000..b7d69e9
--- /dev/null
+++ b/video/newton.NewtonProgram.mp4